使用AHK热字符串，快捷替换为指定内容，自动生成菜单

发个快速进行字符串替换的脚本，可以独立运行，也可以加到QZ的custom.ahk里运行

修改代码段里的以下内容：

前面3个字符是快捷键，自动替换为从第4个字符开始的内容，如果某行是“-”，则在菜单里添加分隔符。

QuickInputList=
(Ltrim
	&Q)2857xxxxxxxxxx@qq.com
	-
	&G)chendddddddddd@szmhzs.com
)

以下为快捷演示：

1、[ad*—-地址类]，快捷键为：]aa
2、[em*—-邮箱类]，快捷键为：]ee
3、[tel*—-电话类] ，快捷键为：]tt
4、[-*—-日期类]，快捷键为：]–
5、[**—-名称类]，快捷键为：]mm

以下为完整代码：

;我的快捷替换短语>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
;[*] 的作用是不用输入终止符即自动替换
;[ad*----地址类];{
:*:]aa:: 
	QuickInputList=
	(Ltrim
		&X)aaaaaaaaaaaaaaaaaaaaaaaaa，aaa，aaaaaaaaaaaaaaaa
		&S)bbbbbbbbbbbbbb，bbbbb，bbbbbbbbbbbbbbb
		&M)cccccccccccccccc，ccc，ccccccccccccc
		-
		&Y)ddddddddddddddddd，徐dddd，18-ddddd
		&P)深圳市eeeeeeeeeeeeeeeeee，潘ee，187eeeeeeeeeeee
		-
		&Z)深圳市fffffffffffffffffffff，周fff，185fffffffffffffffffffff
		&J)深圳gggggggggggggggggg，周ggg，1ggggggggggggggggg
	)
	MySub_QuickInput(QuickInputList)
return
;}
 
 
;[em*----邮箱类] ;{
:*:]ee:: 
	QuickInputList=
	(Ltrim
		&Q)2857xxxxxxxxxx@qq.com
		&G)chendddddddddd@szmhzs.com
	)
	MySub_QuickInput(QuickInputList)
return
;}
 
;[tel*----电话类] ;{
:*:]tt:: 
	QuickInputList=
	(Ltrim
		&C)陈xxxxx，18-xxxxxx
		&Z)张xxxx，1xxx-xxxx-xxxxx
	)
	MySub_QuickInput(QuickInputList)
return
;}
 
;[-*----日期类] ;{
:*:]--::
	QuickInputList=
	(Ltrim
		&1)%A_YYYY%%A_MM%%A_DD%
		&2)%A_YYYY%-%A_MM%-%A_DD%
		&3)%A_YYYY%.%A_MM%.%A_DD%
		&4)%A_YYYY%年%A_MM%月%A_DD%日
		&5)[%A_YYYY%.%A_MM%.%A_DD%]
	)
	MySub_QuickInput(QuickInputList)
return
;}
 
;[**----名称类] ;{
:*:]mm::
	QuickInputList=
	(Ltrim
		&M)深圳市aaaaaaaaaaaaaa
		&L)联ggggggggggggggggggg
		&G)广西dddddddddddddddddd
		-
		&T)厦门gggggggggggg
	)
	MySub_QuickInput(QuickInputList)
return
;}
 
;我的过程或函数>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
MySub_QuickInput(String){
		menu,KyMenu_QuickInput,Add
		menu,KyMenu_QuickInput,DeleteAll
		Loop,parse,String,`n,`r
		{
			if (A_LoopField="")
				continue
			if (A_LoopField="-")
				menu,KyMenu_QuickInput,Add
			else
				menu,KyMenu_QuickInput,Add,% A_LoopField,KyMenu_QuickInput_Handler
		}
		menu,KyMenu_QuickInput,show
	return
 
	KyMenu_QuickInput_Handler:
		PostMessage, 0x50, 0, 67699721, , A
		outputStr:=substr(A_ThisMenuItem,4,strlen(A_ThisMenuItem))
		SendInput   {raw}%outputStr%
	return
}