QQ邮箱ahk发送教程——QQMail库

接收用户邮箱验证码获取位置

发送内容支持中文

Class QQMail
{
    __New(发送用户邮箱, 接收用户邮箱, 发送用户邮箱验证码)
    {
        this.pmsg := ComObject("CDO.Message")
        this.pmsg.From := !Instr(发送用户邮箱, "@qq.com") ? "<" 发送用户邮箱 "@qq.com>" : "<" 发送用户邮箱 ">"
        this.pmsg.To := !Instr(接收用户邮箱, "@") ? 接收用户邮箱 "@qq.com" : 接收用户邮箱
        this.pmsg.BCC := ""	; Blind Carbon Copy, Invisible for all, same syntax as CC
        this.pmsg.CC := ""
        this.fields := Object()
        this.fields.smtpserver := "smtp.qq.com"	; specify your SMTP server
        this.fields.smtpserverport := 465	; 25
        this.fields.smtpusessl := True	; False
        this.fields.sendusing := 2	; cdoSendUsingPort
        this.fields.smtpauthenticate := 1	; cdoBasic
        this.fields.sendusername := !Instr(发送用户邮箱, "@qq.com") ? 发送用户邮箱 "@qq.com" : 发送用户邮箱
        this.fields.sendpassword := 发送用户邮箱验证码
        this.fields.smtpconnectiontimeout := 60
        this.schema := "http://schemas.microsoft.com/cdo/configuration/"
        this.sAttach := ""
    }
    
    设置标题(标题)
    {
        this.pmsg.Subject := 标题
    }
    
    设置内容(内容, 字体 := "gb2312")
    {
        this.pmsg.TextBody := 内容
        this.pmsg.TextBodyPart.Charset := 字体
    }
    
    设置附件(Files)
    {
        this.sAttach := Files
        ; 删除分号以激活附件功能
        ; sAttach := "Path_Of_Attachment" ; 可以添加多个附件
        ; 分隔符是|
    }
    
    发送()
    {
        pfld := this.pmsg.Configuration.Fields

        for field, value in this.fields.OwnProps()
            pfld.Item[this.schema . field] := value
        
        pfld.Update()
        
        if this.sAttach
        {
            Loop Parse, this.sAttach, "|", A_Space A_Tab
                this.pmsg.AddAttachment(A_LoopField)
        }

        this.pmsg.Send()
    }
}

测试代码：

MyQQMail := QQMail("发送用户邮箱", "接收用户邮箱", "发送用户邮箱验证码")
MyQQMail.设置标题("E-mail Test")
MyQQMail.设置内容("Test of sending e-mail directly from AutoHotkey.")
; MyQQMail.设置附件("C:\Users\HP\Desktop\QQMail.ahk|C:\Users\HP\Desktop\Test.ahk")
MyQQMail.发送()