借助CMD命令实现AHK程序热更新

工作中会给同事制作一些AHK辅助程序，编译成EXE文件后分发给同事使用，有时同事反馈一些小问题，或者自己做了一些优化，又得重新分发给同事，虽然我们都处于同一个局域网，也可以访问同一个公共文件夹，但手动替换程序再运行总归有点麻烦，以下AHK代码可实现AHK程序热更新，彻底解决此问题

;首先设定一个局域网文件夹地址，用于存放最新版本的程序文件
路径:="\\192.168.100.16\辅助程序\"
#SingleInstance force
if FileExist(A_ScriptDir . "\更新.bat")
    FileDelete,%A_ScriptDir%\更新.bat
路径:=路径 . A_ScriptName
if FileExist(路径)
{
    FileGetTime,tmp1,%路径%
    FileGetTime,tmp2,%A_ScriptFullPath%
    if (tmp1>tmp2) ;局域网的文件比目前运行的文件修改日期更靠后
    {
        tmp1:=A_ScriptDir . "\更新.bat"
        FileAppend,
        (
        @echo off
        echo 程序有新版本，正在准备更新文件，稍后会重新启动
        ping 127.1 -n 1 >nul 2>nul
        :start
        tasklist /nh|find /i "%A_ScriptName%"
        if ERRORLEVEL 1 goto L1
        goto L2
        :L1
        echo 正在更新文件
        ping 127.1 -n 1 >nul 2>nul
        copy /y %路径% %A_ScriptDir%\
        if exist "%A_ScriptFullPath%" goto L3
        goto L1
        :L3
        cd %A_ScriptDir%\
        start %A_ScriptName%
        exit
        :L2
        echo 等待主程序退出
        ping 127.1 -n 1 >nul 2>nul
        goto start
        ),%tmp1%
        run %tmp1%
        ExitApp
    }
}

可将以上代码保存到一个.ahk脚本文件里，比如”D:\热更新.ahk”，然后只要在新写的脚本开头加上以下代码，便可让新脚本拥有热更新功能

#Include D:\热更新.ahk